/** happy 22 toby
*/

import krister.Ess.*;

Balloon[] balloons = new Balloon[10];
BalloonBar bar = new BalloonBar(-22);
ArrayList psystems;
color particleColor;
int mouseDistX, lastMouseX=0, mouseDistY, lastMouseY;
float xAlter, yAlter;
PFont font;
PImage coney, kitty, unhappy;
AudioChannel pop, cheers, song, no;
int hueCount=0;

void setup() {
  size(400, 400);
  frameRate(100);
  smooth();
  for(int i=0; i<balloons.length; i++)
    balloons[i] = new Balloon();
  Ess.start(this);
  pop = new AudioChannel("pop.aif");
  cheers = new AudioChannel("cheers.aif");
  song = new AudioChannel("bday.aif");
  no = new AudioChannel("no.aif");
  song.play(Ess.FOREVER);
  song.volume(0.4);
  
  psystems = new ArrayList();
  font = loadFont("CenturyGothic-48.vlw");
  coney = loadImage("coney.jpg");
  kitty = loadImage("kittyhead.jpg");
  unhappy = loadImage("mawmaw.jpg");
}

void draw() {
  if(bar.balloons==-22)
    drawWelcome();
  else if(bar.balloons==-21)
    drawGetEm();
  else if(bar.balloons<=0)
    drawDeath();
  else if(bar.balloons>=20)
    drawWin();
  else {
    colorMode(RGB, 255);
//    background(167, 211, 247);
    image(coney,0,0);
    for(int i=0; i<balloons.length; i++) {
      if(balloons[i].y+balloons[i].h < 0) {
        balloons[i] = new Balloon();
        bar.hitTopDecrement();
      }
      balloons[i].exist();
    }
    alterPosition();
    drawParticles();
    bar.exist();
  }
}

void drawWelcome() {
  colorMode(HSB, 255);
  no.stop();
  cheers.stop();
  song.pause();
  background(0);
  textFont(font, 27);
  fill(color(hueCount%255, 255, 255));
  text("do balloons make you happy?", 4, 398);
  hueCount++;
}
void drawGetEm() {
  colorMode(RGB, 255);
  no.stop();
  cheers.stop();
  song.pause();
  background(0);
  textFont(font, 140);
  fill(color(hueCount%255, 0, 0));
  text("GET", 70, 170);
  text("'EM", 80, 350);
  hueCount+=40;
}
void drawDeath() {
  song.stop();
  no.play(Ess.FOREVER);
  background(0);
  textFont(font, 32);
  fill(255);
  image(unhappy, 0, 50);
  text("your birthday is not happy.", 1, 50);//height/2);
}
void drawWin() {
  background(167, 211, 247);
  image(kitty,0,0);
  textFont(font, 32);
  stroke(255);
  strokeWeight(2);
  fill(163, 232, 61);
  rect(-2, 318, width+3, 151);
  fill(255);
  text("popped balloons\ncelebrate your happiness", 5, 350);
  textFont(font, 12);
  text("replay", 360, 10);
  song.pause();
  cheers.play(1);
}

void alterPosition() {
  mouseDistX = mouseX-lastMouseX;
  mouseDistY = mouseY-lastMouseY;
  lastMouseX=mouseX;
  lastMouseY=mouseY;
  xAlter += constrain(mouseDistX/8, -10, 10);
  yAlter += constrain(mouseDistY/12, -10, 10);
  xAlter *= 0.9;
  yAlter *= 0.9;
}

void mousePressed() {
  randomSeed(millis());
  if(bar.balloons==-22) {
    bar.balloons = -21;
    return;
  } else if(bar.balloons==-21) {
    bar.balloons = 10;
    return;
  } else if(bar.balloons<=0) {
    bar.balloons = -22;
    for(int i=0; i<balloons.length; i++)
      balloons[i] = new Balloon();
    return;
  } else if(bar.balloons>=20) {
    if(mouseY<10 && mouseX>40) {
      song.cue(0);
      psystems = new ArrayList();
      for(int i=0; i<balloons.length; i++)
        balloons[i] = new Balloon();
      bar.balloons=-22;
    }
  }
  for(int i=balloons.length-1; i>=0; i--) {
    if(balloons[i].checkOver(mouseX, mouseY)) {
      pop.play(1);
      particleColor = balloons[i].c;
      psystems.add(new ParticleSystem((int)(balloons[i].s*40), new Vector3D(mouseX,mouseY)));
      balloons[i] = new Balloon();
      bar.increment();
      break;
    }
  }
}

void stop() {
  Ess.stop();
  super.stop();
}