/* 'Final' combination lock
 * Kevin Cox
 * kevin.cox@nyu.edu
*/
const int numSwitches = 3;
int switches[numSwitches] = { 2, 3, 4 };
int led = 12;
const int ledCount = 9;
int leds[ledCount] = { 5, 6, 7, 8, 9, 10, 11, 12, 13 };

const int codeLength = 9;
// this is the code
int code[codeLength] = { 
    2, 1, 0, 1, 0, 2, 0, 2, 1 };
//  2, 1, 0, 2, 1, 0, 2, 1, 0 };
int input[codeLength];
int codeCount, waitForLow;
boolean locked;

void setup() {
  Serial.begin(9600);
  locked = true;
  codeCount = 0;
  waitForLow = -1;
  pinMode(switches[0], INPUT);
  pinMode(switches[1], INPUT);
  pinMode(switches[2], INPUT);
  for(int ld=0; ld<ledCount; ld++) {
    pinMode(leds[ld], OUTPUT);
  }
  Serial.println("begin");
}

void loop() {
  if(locked) {
    // check the three switches
    for(int i=0; i < numSwitches; i++) {
      // waitForLow is negative when we're not
      // waiting for a switch to go low
      if(waitForLow == -1) {
        if(digitalRead(switches[i]) == HIGH) {
          waitForLow=i;
          digitalWrite(leds[codeCount],HIGH);
        }
      } else {
        // now the switch is low
        if(digitalRead(switches[waitForLow]) == LOW) {
          input[codeCount] = waitForLow;
          waitForLow = -1;
          delay(250); // delay to fix junky switches
          codeCount++;
          Serial.print(codeCount);
          Serial.print(" of ");
          Serial.println(codeLength);
        }
      }
    }
    // the whole code has been entered
    if(codeCount == (codeLength)) {
      Serial.println("complete");
      boolean success = true;
      // loop through and check the code
      for(int c=0; c < codeLength; c++) {
        if(input[c] != code[c]) {
          success = false;
          Serial.println("badcode");
          codeCount = 0;
          for(int e=0; e<ledCount; e++) {
            digitalWrite(leds[e], LOW);
          }
          break;
        }
      }
      if(success) { // code was good!
        Serial.println("unlocked");
        locked = false;
      }
    }
  } else { // switch is unlocked
    // reset if all 3 buttons are held down
    if((digitalRead(switches[0]) == HIGH) &&
        (digitalRead(switches[1]) == HIGH) &&
        (digitalRead(switches[2]) == HIGH)) {
      locked = true;
      codeCount = 0;
      for(int e=0; e<ledCount; e++) {
        digitalWrite(leds[e], LOW);
      }
      delay(500);
    }
  }
}

// FUNctions!
void blink(int pin, int ms) {
  digitalWrite(pin, HIGH);
  delay(ms);
  digitalWrite(pin, LOW);
  delay(ms);
}
void multiBlink(int pin, int ms, int times) {
  for(times; times>0; times--) {
    blink(pin,ms);
  }
}